#COMMENT

     Pirate's Adventure

     Original game by Scott and Alexis Adams

     Transcribed from a BASIC listing in the December 1980 issue of BYTE.

     Adapted for the Adventure Game Toolkit by David Malmberg.


Walkthru for PIRATE ADVENTURE
 
From the London Flat room, first get the crackers and rum.  Wear the sneakers.
Go stairs.  Get Book - twice.  Go Passage, then East.
 
Get the torch.  Open the duffel bag.  Get the matches.  Go West twice. Read
the book (it tells that the magic word is Yoho.)  Go Window, and say YOHO.
You've been teleported to a sandy island beach.
 
Drop book.  Go East.  Go Shack.  Give rum to the Pirate.  He will run away.
Give the crackers to the parrot.  Go West, then East to the cave-ridden hill.
 
Go Path, to the top of the hill.  Go Crack.  Light the torch.  There's a shed
containing lumber and sails.  Go shed, get the hammer and water wings, then go
North, through the crack.  Unlight Torch.  Go down, then West (twice) to the
beach.
 
Drop the wings, the torch, and the matches.  Get the book.  Say YOHO. You're
back on the ledge again.  Enter to go back inside.  Go passage. Next East, to
find the drunken pirate.  Get the rum bottle.  Drink rum.  Go downstairs to
the room where you began.  Get Nails.  Get Rug.  Drop the rug. Get the keys.
Go upstairs to the window ledge.  Say YOHO.
 
You are again teleported to the beach.  Drop the book, hammer, and nails.  Get
water wings and Go Lagoon.  If the tide is not coming in, wait for it.  Go
North.  Get some water and then get the fish.  Go South twice.  Drop the
wings.  Get the torch and matches.  Go East twice. You'll be at the bottom of
the hill.  Light the torch.  Go cave.  Go down.  Feed the fish to the crocs.
Drop the bottle.  Unlock the door. Go Hallway.  Go East.  Go to the shed.  Get
shovel.  Go north.  Get the lumber and sails.  Go West.  Go to the pit, up,
and West.  Unlight torch.  Go back to the beach.  Get water wings.
 
Drop the lumber, sails, torch, and matches.  Go back to the shack.  Open the
chest (use the keys).  Look inside.  Get the map and the plans.  Go back to
the beach.  Get water wings.  Go to the lagoon.
 
If the tide is in, wait for it to go out.  Dig up the anchor.  Get anchor.  Go
South to the beach.  Drop all.  Build Ship.  The Pirate Ship will be completed
and then it will disappear.

Get book.  Say YOHO.  Go wake up the sleeping pirate.  Go back to the window
and say YOHO again.  Drop the book.  If you like jokes, get the mongoose you
see around the hut on the island.  Get shovel and map.  Go to the lagoon.
Also, say WEIGH ANCHOR.  Go Ship, and Set Sail.  You are now at Treasure
Island.
 
Go Ashore.  Dig.  Go South, then East into the field.  Pace 30.  Dig. You
uncover a wooden box.  Get box.  Drop the shovel.  Go Monastery. Throw the
mongoose at the snakes (if you got it.)  Eventually the parrot will chase off
the snakes.  Get the doubloons.
 
South.  West.  Wake up the pirate.  Go North to the beach.  Go Dinghy.  Set
Sail.  Go Ashore.  Get hammer.  Get nails.  Open the box, then examine it.
Get the stamps.  Drop the hammer and box.  Get the book.  Say YOHO.  Enter and
then go down the stairs.  Drop the treasures (stamps and doubloons) and say
Score.  That's it.

#END_COMMENT

#OPTIONS /Labels[] /Messages""

TITLE
COLORS WHITE YELLOW BLACK YELLOW RED
P I R A T E ' S   A D V E N T U R E

by Scott and Alexis Adams

Adapted for the Adventure Game Toolkit by David Malmberg

****
END_TITLE


INSTRUCTIONS

During your adventure, I will be your eyes and hands.  I know of places,
actions, and things.

Your commands can be expressed in the format:

  <verb phrase> <(multiple) noun phrase(s)> <preposition> <noun phrase/object>

For example:

         PUT THE GREEN ROCK BEHIND THE OAK TREE
         READ MY POETRY BOOK
         SWIM IN THE SWIMMING POOL
         EXAMINE THE GOLD RING, THE DWARF AND THE SILVER NECKLACE
         EAT THE CELERY AND THE ONION
         SHOOT THE BURGLAR WITH THE REVOLVER
         ATTACK HIM
           ("HIM" will refer to last noun mentioned, e.g., the burglar)
         GET THE BOOK (also: TAKE THE BOOK)
         READ IT
           ("IT" will refer to last noun mentioned, e.g., the book)
         GET ALL

Compound commands can be created by connecting single commands (like those
above) with "AND", "THEN" or the punctuation symbols "," or ";" to connect two
or more separate commands, such as:

         CLIMB DOWN THE LADDER THEN SOUTH, WEST AND NORTHWEST
         GET THE CLOAK AND THEN EXAMINE IT; READ THE LABEL
         DROP THE FOOD AND THE BOTTLE THEN UNLOCK THE DOOR AND THEN LEAVE

The game uses a number of special commands for various "housekeeping" chores.
These are all pretty standard for most adventure games.  Specifically:
HELP, SCORE, INVENTORY, VERBOSE, LIST EXITS, SAVE, RESTORE, SCRIPT, UNSCRIPT
and QUIT.

The function keys have been predefined to stand for several of the most
frequently used commands.  Similarly, the cursor keys correspond to the
various movement/compass directions.

Hitting the '?' key (during the game) will display a diagram of keys and their
definitions.
END_INSTRUCTIONS

VERB
GET PRY PULL CATCH
EXTINGUISH UNLIGHT
Dummy_Verb1 GO CLIMB PACE
Dummy_Verb2 YOHO
Dummy_Verb3 WAKE
Dummy_Verb4 DIG
Dummy_Verb5 FIND
Dummy_Verb7 BUILD
Dummy_Verb8 SET
Dummy_Verb9 WEIGH
Dummy_Verb10 CAST
Dummy_Verb11 SAIL
Dummy_Verb12 JUMP
Dummy_Verb13 SAY
Dummy_Verb14 POUR EMPTY
Dummy_Verb15 FILL
Dummy_Verb16 AWAY XYZZY PLOVER PLUGH
Dummy_Verb17 BURY
Dummy_Verb18 BREAK KICK
Dummy_Verb19 KISS
Dummy_Verb20 GIVE FEED
END_VERB

VOCABULARY
! This is the default AGT verb list for the "menu-driven" parser for PIRATE

! AGAIN should be the first A-verb
1 Again
2 Attack
3 Attack With
1 away
2 Break
3 Break with
1 Brief
2 build
2 bury
1 bunyon
2 Burn
2 cast
2 Chop
2 Close
2 Climb up
2 Climb down
2 climb to
2 Cut
! DOWN should be the first D-verb
1 Down
1 Dig
2 Drop
2 Drink
! EAST should be the first E-verb
1 East
2 Examine
2 Eat
2 empty
2 Enter
1 Exit
2 Extinguish
2 feed
3 Feed to
3 Fill with
2 find
2 free
! GET should be the first G-verb
2 Get
3 Give to
2 Go to
! HELP should be the first H-verb
1 Help
2 Heat
2 Hit
3 Hit with
2 Hold
! INVENTORY should be the first I-verb
1 Inventory
2 ignite
1 Jump
2 Jump to
2 kick
2 Kill
3 Kill With
2 kiss
! LOOK AROUND should be the first L-verb
1 Look around
2 Look at
1 List Exits
2 Light
3 Light With
3 Lock with
! NORTH should be the first N-verb
1 North
1 Northeast
1 Northwest
1 no
! OPEN should be the first O-verb
2 Open
2 Pace
3 Put in
3 Pour on
3 Pour in
! QUIT should be the first Q-verb
1 Quit
! READ should be the first R-verb
2 Read
2 release
2 Rub
1 Restore
! SOUTH should be the first S-verb
1 South
1 Southeast
1 Southwest
1 Score
1 Save
2 sail
2 Set
1 say
1 Scream
2 Scream At
1 Script
1 Shout
1 Sit
2 smash
1 stop
1 Swim
! TAKE should be the first T-verb
2 Take
2 Throw
3 Throw at
! UP should be the first U-verb
1 Up
2 unlight
2 Unlock
1 Unscript
! VERBOSE should be the first V-verb
1 Verbose
1 Version
! WEST should be the first W-verb
1 West
1 Wait
2 wake
2 weigh
1 Yell
2 Yell At
1 yes
1 yoho
END_VOCABULARY

#DEFINE [noun weight] 13
#DEFINE [NoWhere] 0

STARTING_ROOM [London Apartment]

ROOM [London Apartment]
London Apartment
UP [Alcove]
END_ROOM

ROOM_DESCR [London Apartment]
You are in a London apartment.
END_ROOM_DESCR

COMMAND GO
IsSomewhere [parrot] (* parrot exists *)
FlagON [Has befriended parrot]
PrintMessage "The parrot flies along behind you."
BlankLine
END_COMMAND

COMMAND GO STAIRS
AtLocation [London Apartment]
GoToRoom [Alcove]
PrintMessage "You walk up the stairs to the room above."
BlankLine
DoneWithTurn
END_COMMAND

NOUN [Flight of Stairs]
Stairs
Flight
A flight of stairs leads upward.
LOCATION [London Apartment]
UNMOVABLE
END_NOUN

NOUN_DESCR [Flight of Stairs]
The stairs are made of wood and creak as you step on them.
END_NOUN_DESCR

NOUN [Sign on wall 'Return treasures here...say SCORE.']
Sign
Large
There is a large sign on the wall.
LOCATION [London Apartment]
UNMOVABLE
READABLE
END_NOUN

NOUN_DESCR [Sign on wall 'Return treasures here...say SCORE.']
The sign on wall says 'Return treasures here...say SCORE.'
END_NOUN_DESCR

TEXT [Sign on wall 'Return treasures here...say SCORE.']
It says 'Return treasures here...say SCORE.'
END_TEXT

NOUN [Rug in room]
Rug
Small
A small rug covers part of the floor.
LOCATION [London Apartment]
UNMOVABLE
END_NOUN

NOUN_DESCR [Rug in room]
The rug is brown and sort of ugly.  It is nailed to the floor.
END_NOUN_DESCR

NOUN [Rug]
Rug
Small
A small rug covers part of the floor.
LOCATION [NoWhere]
END_NOUN

NOUN_DESCR [Rug]
The rug is brown and sort of ugly.
END_NOUN_DESCR

NOUN [Nails]
Nails
Iron
There are a bunch of iron nails here.
LOCATION [NoWhere]
PLURAL
NOUN_SYNONYMS NAIL
END_NOUN

NOUN_DESCR [Nails]
They are about "20 penny" iron nails.
END_NOUN_DESCR

NOUN [ring of keys]
ring
key
There are a ring of keys here.
LOCATION [NoWhere]
WEIGHT 2
SIZE 2
NOUN_SYNONYMS KEY KEYS
PLURAL
END_NOUN

NOUN_DESCR [ring of keys]
The keys are made of iron and are attached to an iron ring.
END_NOUN_DESCR

NOUN [Non-skid sneakers]
sneakers
Non-skid
There are some non-skid sneakers here.
LOCATION [London Apartment]
WEARABLE
NOUN_SYNONYMS SHOES
END_NOUN

NOUN_DESCR [Non-skid sneakers]
The sneakers are just your size -- 15 EEEEEs.
END_NOUN_DESCR

NOUN [Crackers]
Crackers
stale
There are some stale crackers here.
LOCATION [London Apartment]
NOUN_SYNONYMS SALTINE SALTINES CRACKER
PLURAL
EDIBLE
END_NOUN

NOUN_DESCR [Crackers]
The crackers are plain saltines.  They are stale.
END_NOUN_DESCR

NOUN [water bottle]
water
bottle-of
There is a small bottle of sea water here.
LOCATION [NoWhere]
WEIGHT [noun weight]
NOUN_SYNONYMS BOTTLE
END_NOUN

NOUN_DESCR [water bottle]
The bottle is shaped like a rum bottle and looks like it would hold about a
quart of liquid.  It is full of sea water.
END_NOUN_DESCR

NOUN [rum bottle]
rum
bottle-of
There is a small bottle of rum here.
LOCATION [London Apartment]
WEIGHT [noun weight]
NOUN_SYNONYMS BOTTLE
END_NOUN

NOUN_DESCR [rum bottle]
The bottle is shaped like a rum bottle and looks like it would hold about a
quart of liquid.  It is full of rum.
END_NOUN_DESCR

NOUN [empty bottle]
bottle
empty
There is a small empty bottle here.
LOCATION [NoWhere]
WEIGHT [noun weight]
END_NOUN

NOUN_DESCR [empty bottle]
The bottle is shaped like a rum bottle and looks like it would hold about a
quart of liquid.  It is currently empty.
END_NOUN_DESCR

ROOM [Alcove]
Alcove
DOWN [London Apartment]
END_ROOM

ROOM_DESCR [Alcove]
You are in an alcove at the top of some stairs.
END_ROOM_DESCR

HELP [Alcove]
Reading expands the mind!
END_HELP

COMMAND GO STAIRS
AtLocation [Alcove]
GoToRoom [London Apartment]
PrintMessage "You walk down the stairs to the room below."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO WINDOW
AtLocation [Alcove]
GoToRoom [Outside Window]
PrintMessage "You climb out the window to the ledge outside."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO PASSAGE
AtLocation [Alcove]
Present [secret passage]
GoToRoom [Secret Passageway]
PrintMessage "You go behind the bookcase and enter the secret passageway."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ENTER
AtLocation [Alcove]
Present [secret passage]
GoToRoom [Secret Passageway]
PrintMessage "You go behind the bookcase and enter the secret passageway."
BlankLine
DoneWithTurn
END_COMMAND
NOUN [Open Window]
window
open
There is an open window here.
LOCATION [Alcove]
UNMOVABLE
END_NOUN

NOUN_DESCR [Open Window]
The window is open.  As you look through it, you can see the streets of London
below you.
END_NOUN_DESCR

NOUN [bookcase]
bookcase
full
A bookcase filled with classics covers the wall.
LOCATION [Alcove]
UNMOVABLE
OPENABLE
OPEN
SIZE 100
WEIGHT
END_NOUN

NOUN_DESCR [bookcase]
The bookcase covers most of one wall and is quite full of a wide variety of
books -- mostly classics.
END_NOUN_DESCR

NOUN [Large leather bound book]
book
leather-bound
You see a large leather-bound book.
LOCATION [bookcase]
READABLE
END_NOUN

NOUN_DESCR [Large leather bound book]
The book is "Treasure Island."  It looks like a first edition.
END_NOUN_DESCR

TEXT [Large leather bound book]
There's a word engraved in the flyleaf - YOHO ... and a message - 'Long John
Silver left 2 treasures on Treasure Island'.
END_TEXT

NOUN [secret passage]
passage
secret
The bookcase has been moved, revealing a secret passage.
LOCATION [NoWhere]
UNMOVABLE
NOUN_SYNONYMS BOOKCASE
END_NOUN

NOUN_DESCR [secret passage]
The bookcase has been moved out from the wall revealing a secret passage which
is so dark that you can't see anything beyond the bookcase.
END_NOUN_DESCR


ROOM [Secret Passageway]
Secret Passageway
EAST [Musty Attic]
WEST [Alcove]
END_ROOM

ROOM_DESCR [Secret Passageway]
You are in a secret passageway.
END_ROOM_DESCR


ROOM [Musty Attic]
Musty Attic
WEST [Secret Passageway]
END_ROOM

ROOM_DESCR [Musty Attic]
You are in a musty attic.
END_ROOM_DESCR

NOUN [unlit torch]
torch
unlit
There is an unlit torch nearby.
LOCATION [Musty Attic]
WEIGHT 2
SIZE 2
IS_LIGHT
END_NOUN

NOUN_DESCR [unlit torch]
The torch is about 3 feet long and has rags tied around one end.  The rags
have been soaked in oil and should burn easily.
END_NOUN_DESCR

NOUN [Duffle bag]
bag
duffle
You see large duffle bag.  It looks like the kind that pirates have.
LOCATION [Musty Attic]
WEIGHT 10
CLOSABLE
CLOSED
SIZE 10
NOUN_SYNONYMS FLAP
END_NOUN
NOUN_DESCR [Duffle bag]
The pirate's duffle bag is about a foot around and three feet tall.  It is
brown canvas.  It has a flap which can be opened and closed.
END_NOUN_DESCR

NOUN [Wooden matches]
matches
wooden
There is a box of wooden matches.
LOCATION [Duffle bag]
WEIGHT 2
SIZE 2
NOUN_SYNONYMS MATCH
PLURAL
END_NOUN

NOUN_DESCR [Wooden matches]
The matches are made out of wood.  You light one and it lights easily and
burns brightly for about a minute before going out.
END_NOUN_DESCR

NOUN [soggy matches]
matches
soggy
There is a box of soggy matches here.
LOCATION [NoWhere]
WEIGHT 2
SIZE 2
NOUN_SYNONYMS MATCH
PLURAL
END_NOUN

NOUN_DESCR [soggy matches]
The matches are too wet to light.
END_NOUN_DESCR

NOUN [blazing torch]
torch
blazing
The torch is blazing brightly.
LOCATION [NoWhere]
WEIGHT 5
SIZE 12
IS_LIGHT
END_NOUN

NOUN_DESCR [blazing torch]
The torch is blazing and gives a nice bright light.
END_NOUN_DESCR

NOUN [Pieces of broken rum bottles]
Pieces
broken
There are some glass pieces of broken rum bottles.
LOCATION [Musty Attic]
NOUN_SYNONYMS GLASS
END_NOUN

NOUN_DESCR [Pieces of broken rum bottles]
The pieces are quite small and made of very sharp glass.  Be careful!
END_NOUN_DESCR


ROOM [Outside Window]
Outside Window
ENTER [Alcove]
END_ROOM

ROOM_DESCR [Outside Window]
You are on a ledge outside a window of a tall building.
END_ROOM_DESCR

ROOM [Sandy Beach]
Sandy Beach
EAST [Meadow]
WEST [Shallow Lagoon]
END_ROOM

ROOM_DESCR [Sandy Beach]
You are on a sandy beach on a tropical isle.
END_ROOM_DESCR

HELP [Sandy Beach]
There are multiple exits here.
END_HELP

COMMAND GO LAGOON
AtLocation [Sandy Beach]
GoToRoom [Shallow Lagoon]
PrintMessage "You walk west down to the lagoon."
BlankLine
DoneWithTurn
END_COMMAND

NOUN [Lagoon]
Lagoon
The
There is a large lagoon to the west.
LOCATION [Sandy Beach]
UNMOVABLE
END_NOUN

NOUN_DESCR [Lagoon]
The lagoon is quite large and has very blue clear water.
END_NOUN_DESCR

NOUN [Sand]
Sand
Beach
There is sand everywhere.
LOCATION [Sandy Beach]
UNMOVABLE
END_NOUN

NOUN_DESCR [Sand]
The sand is fairly ordinary.  It is white, clean and quite fine.
END_NOUN_DESCR

NOUN [Small ship's keel and mast]
keel
ship's
There is a small ship's keel and mast here.
LOCATION [Sandy Beach]
NOUN_SYNONYMS MAST
END_NOUN

NOUN_DESCR [Small ship's keel and mast]
The keel and mast are for a small ship.
END_NOUN_DESCR

NOUN [pirate ship]
ship
pirate
A ship is anchored off-shore.  Its 'Jolly Roger' waves in the breeze.
LOCATION [NoWhere]
NOUN_SYNONYMS BOAT
END_NOUN

NOUN_DESCR [pirate ship]
It is obviously a pirate ship.  You can see its 'Jolly Roger' flapping in the
light breeze.
END_NOUN_DESCR

COMMAND GO BOAT
Present [pirate ship]
PrintMessage "You swim out to the pirate ship."
GoToRoom [On Pirate Ship]
DoneWithTurn
END_COMMAND

COMMAND GO ASHORE
FlagOFF [Has sailed to 'Treasure Island']
AtLocation [On Pirate Ship]
SendToRoom [Dinghy] [Shallow Lagoon]
GoToRoom [Shallow Lagoon]
PrintMessage "You row your dinghy to the island."
TurnFlagOFF [On Treasure Island]
BlankLine
DoneWithTurn
END_COMMAND

ROOM [Maze of Caves 7]
Maze of Caves 7
SOUTH [Maze of Caves 12]
EAST [Maze of Caves 19]
WEST [Foot of Hill]
DOWN [In a Pit]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [Maze of Caves 7]
You are in a maze of caves.  There is a narrow opening to the west with a
little day-light shinning through it.  Passages lead in all directions.
END_ROOM_DESCR

ROOM [Meadow]
Meadow
EAST [Foot of Hill]
WEST [Sandy Beach]
SOUTH [Grass Shack]
END_ROOM

ROOM_DESCR [Meadow]
You are in a meadow.  The beach is to the west.  A hill rises to the east.
END_ROOM_DESCR

COMMAND GO BEACH
AtLocation [Meadow]
GoToRoom [Sandy Beach]
PrintMessage "You walk west to the beach."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO HILL
AtLocation [Meadow]
GoToRoom [Foot of Hill]
PrintMessage "You walk east to the foot of the hill."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO SHACK
AtLocation [Meadow]
GoToRoom [Grass Shack]
PrintMessage "You walk south and enter the grass shack."
BlankLine
DoneWithTurn
END_COMMAND

NOUN [Hill]
hill
small
There is a hill.
LOCATION [NoWhere]
NOUN_SYNONYMS PATH
END_NOUN

NOUN_DESCR [Hill]
The noun is just a "dummy" to define the noun HILL.
END_NOUN_DESCR

NOUN [Beach]
beach
small
There is a beach.
LOCATION [NoWhere]
END_NOUN

NOUN_DESCR [Beach]
The noun is just a "dummy" to define the noun BEACH.
END_NOUN_DESCR

NOUN [Shack]
Shack
Grass
You can see a grass shack to the south.
LOCATION [Meadow]
UNMOVABLE
END_NOUN

NOUN_DESCR [Shack]
The grass shack looks like it would blow away in a strong wind.
END_NOUN_DESCR

NOUN [Mongoose]
Mongoose
small
There is a small mongoose here.
LOCATION [Meadow]
END_NOUN

NOUN_DESCR [Mongoose]
The mongoose looks pretty ordinary.
END_NOUN_DESCR

ROOM [Grass Shack]
Grass Shack
WEST [Meadow]
END_ROOM

ROOM_DESCR [Grass Shack]
You are in a grass shack.  There is an opening to the west.
END_ROOM_DESCR

NOUN [treasure chest]
chest
treasure
You see a jewel-encrusted, golden treasure chest.
LOCATION [Grass Shack]
WEIGHT 30
SIZE 30
CLOSABLE
CLOSED
LOCKABLE
LOCKED
KEY [ring of keys]
END_NOUN

NOUN_DESCR [treasure chest]
The chest is made out of gold and has been encrusted with many precious
jewels.  The chest is about one foot square.  A key hole is in the center of
the top of the chest.
END_NOUN_DESCR

NOUN [Set of plans]
plans
Set
You see a set of drawings.
LOCATION [treasure chest]
WEIGHT 10
SIZE 10
PLURAL
NOUN_SYNONYMS PLAN DRAWING DRAWINGS
READABLE
END_NOUN

NOUN_DESCR [Set of plans]
They're plans to build 'Jolly Roger' (a pirate ship!) - you'll need a hammer,
nails, lumber, an anchor, sails and a keel.
END_NOUN_DESCR

TEXT [Set of plans]
It says that you'll need a hammer, nails, lumber, an anchor, sails and a keel.
END_TEXT

NOUN [Map]
Map
pirate
There is a pirate's map here.
LOCATION [treasure chest]
WEIGHT 10
SIZE 10
READABLE
END_NOUN

NOUN_DESCR [Map]
It's a map to Treasure Island.  At the bottom it says 'Go 30 paces then dig!'
END_NOUN_DESCR

TEXT [Map]
At the bottom of the map, is a message that says 'Go 30 paces then dig!'
END_TEXT

NOUN [parrot]
parrot
green
You see a small green parrot flying madly about.
LOCATION [Grass Shack]
NOUN_SYNONYMS POLLY
END_NOUN

NOUN_DESCR [parrot]
The parrot is sort of yellowish-green. It is about 8 inches tall.  The parrot
appears somewhat nervous and keeps flying about.
END_NOUN_DESCR

NOUN [Sleeping pirate]
pirate
Sleeping
There is a sleeping pirate here.  He is snoring loudly.
LOCATION [NoWhere]
END_NOUN

NOUN_DESCR [Sleeping pirate]
The pirate is sleeping very soundly and very loudly.
END_NOUN_DESCR

NOUN [Wicked-looking pirate]
pirate
Wicked-looking
There is a mean and wicked-looking pirate here.
LOCATION [Grass Shack]
END_NOUN

NOUN_DESCR [Wicked-looking pirate]
The pirate does not look very friendly.
END_NOUN_DESCR

ROOM [In Ocean]
In Ocean
NORTH [In Ocean]
SOUTH [Shallow Lagoon]
EAST [In Ocean]
WEST [In Ocean]
END_ROOM

ROOM_DESCR [In Ocean]
You are in the ocean.
END_ROOM_DESCR

NOUN [fish]
fish
large
You see several large fish swimming about in the water.
PLURAL
LOCATION [In Ocean]
NOUN_SYNONYMS MACKEREL
END_NOUN

NOUN_DESCR [fish]
The fish look like mackerel.
END_NOUN_DESCR

NOUN [mackerel]
fish
large
You see several large mackerel.  They are still alive, barely.
PLURAL
LOCATION [NoWhere]
NOUN_SYNONYMS MACKEREL
END_NOUN

NOUN_DESCR [mackerel]
The fish are almost dead.
END_NOUN_DESCR

ROOM [In a Pit]
In a Pit
UP [Maze of Caves 7]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [In a Pit]
You are in a deep pit.
END_ROOM_DESCR

HELP [In a Pit]
The tide is changing - matey.
END_HELP

COMMAND GO DOOR
AtLocation [In a Pit]
Present [Open doorway with hallway beyond]
GoToRoom [Long Hallway]
PrintMessage [You walk through the open door to the hallway beyond.]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ENTER DOOR
AtLocation [In a Pit]
Present [Open doorway with hallway beyond]
GoToRoom [Long Hallway]
PrintMessage [You walk through the open door to the hallway beyond.]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO HALLWAY
AtLocation [In a Pit]
Present [Open doorway with hallway beyond]
GoToRoom [Long Hallway]
PrintMessage [You walk through the open door to the hallway beyond.]
BlankLine
DoneWithTurn
END_COMMAND

MESSAGE [You walk through the open door to the hallway beyond.]
You walk through the open door to the hallway beyond.
END_MESSAGE

NOUN [Locked door #2]
door
Locked
There is a locked door here.
LOCATION [In a Pit]
UNMOVABLE
END_NOUN

NOUN_DESCR [Locked door #2]
The door is locked tight.
END_NOUN_DESCR

NOUN [Open doorway with hallway beyond]
Doorway
Open
Through an open doorway you can see a long hallway.
LOCATION [NoWhere]
UNMOVABLE
END_NOUN

NOUN_DESCR [Open doorway with hallway beyond]
Beyond the open doorway is a long hallway.
END_NOUN_DESCR


NOUN [Mean and hungry looking crocodiles]
crocodiles
hungry
You see several mean and hungry-looking crocodiles.
PLURAL
LOCATION [In a Pit]
NOUN_SYNONYMS CROCS
END_NOUN

NOUN_DESCR [Mean and hungry looking crocodiles]
The crocodiles look very hungry.  Be careful!
END_NOUN_DESCR

ROOM [Maze of Caves 12]
Maze of Caves
NORTH [Maze of Caves 7]
SOUTH [Maze of Caves 7]
EAST  [Maze of Caves 19]
WEST [Maze of Caves 13]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [Maze of Caves 12]
You are in a maze of caves.
END_ROOM_DESCR

ROOM [Maze of Caves 13]
Maze of Caves
SOUTH [Maze of Caves 7]
EAST [Maze of Caves 7]
WEST [Maze of Caves 12]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [Maze of Caves 13]
You are in a maze of caves.
END_ROOM_DESCR

ROOM [Foot of Hill]
Foot of Hill
WEST [Meadow] 
UP [Top of Hill]
END_ROOM

ROOM_DESCR [Foot of Hill]
You are at the foot of a small hill.  The hill is riddled with caves.  A path
leads up to the top of the hill.  To the west is a meadow.
END_ROOM_DESCR

HELP [Foot of Hill]
There are multiple exits here.
END_HELP

COMMAND CLIMB HILL
AtLocation [Foot of Hill]
GoToRoom [Top of Hill]
PrintMessage "You climb up the path to the top of the hill."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO CAVE
AtLocation [Foot of Hill]
GoToRoom [Maze of Caves 7]
PrintMessage "You climb up to one of the caves and enter it."
BlankLine
DoneWithTurn
END_COMMAND

ROOM [In Tool Shed]
Tool Shed
NORTH [In Large Cavern]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [In Tool Shed]
You are in a tool shed.  The door is to the north.
END_ROOM_DESCR

NOUN [Shovel]
Shovel
large
There is a large shovel here.
LOCATION [In Tool Shed]
SIZE 25 (* Wont fit through crack *)
WEIGHT 25 (* Wont fit through crack *)
END_NOUN

NOUN_DESCR [Shovel]
The shovel has a long and handle and its blade is a little rusty.
END_NOUN_DESCR

NOUN [Claw hammer]
hammer
Claw
You see a big claw hammer.
LOCATION [In Tool Shed]
SIZE 2 (* Will fit through crack *)
WEIGHT 2 (* Will fit through crack *)
END_NOUN

NOUN_DESCR [Claw hammer]
The claw hammer is quite heavy.  You swing it a few times.  It feels good in
your hand.
END_NOUN_DESCR

NOUN [Water wings]
wings
Water
There are some water wings here.
LOCATION [In Tool Shed]
SIZE 2 (* Will fit through crack *)
WEIGHT 2 (* Will fit through crack *)
END_NOUN

NOUN_DESCR [Water wings]
The water wings look like they would allow you to float.
END_NOUN_DESCR


ROOM [Long Hallway]
Long Hallway
EAST [In Large Cavern]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [Long Hallway]
You are in a long hallway.
END_ROOM_DESCR

COMMAND GO DOOR
AtLocation [Long Hallway]
Present [Open doorway with pit beyond]
GoToRoom [In a Pit]
PrintMessage [You walk through the door to the pit beyond.]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ENTER DOOR
AtLocation [Long Hallway]
Present [Open doorway with pit beyond]
GoToRoom [In a Pit]
PrintMessage [You walk through the door to the pit beyond.]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO PIT
AtLocation [Long Hallway]
Present [Open doorway with pit beyond]
GoToRoom [In a Pit]
PrintMessage [You walk through the door to the pit beyond.]
BlankLine
DoneWithTurn
END_COMMAND

MESSAGE [You walk through the door to the pit beyond.]
You walk through the open door to the pit beyond.
END_MESSAGE

NOUN [Locked door]
door
Locked
There is a locked door here.  It is locked on the other side.
LOCATION [Long Hallway]
UNMOVABLE
END_NOUN

NOUN_DESCR [Locked door]
The door is locked on the other side.  You can't open it or even unlock it
from this side.
END_NOUN_DESCR

NOUN [Open doorway with pit beyond]
Doorway
Open
Through an open doorway you can see a large pit.
LOCATION [NoWhere]
UNMOVABLE
END_NOUN
NOUN_DESCR [Open doorway with pit beyond]
Beyond the open doorway is a large pit.
END_NOUN_DESCR

ROOM [In Large Cavern]
Large Cavern
WEST [Long Hallway]
SOUTH [In Tool Shed]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [In Large Cavern]
You are in a large cavern.  There is a narrow crack with day-light shining
through it.
END_ROOM_DESCR

COMMAND GO SHED
AtLocation [In Large Cavern]
GoToRoom [In Tool Shed]
DoneWithTurn
END_COMMAND

COMMAND GO CRACK
AtLocation [In Large Cavern]
LoadWeightLT 20
GoToRoom [Top of Hill]
PrintMessage [You just manage to squeeze]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO CRACK
AtLocation [In Large Cavern]
LoadWeightGT 19
PrintMessage [You can't squeeze through the crack.]
DoneWithTurn
END_COMMAND

NOUN [Tool Shed]
shed
Tool
There is a walk-in tool shed to the south.  Its door is open.
LOCATION [In Large Cavern]
UNMOVABLE
END_NOUN

NOUN_DESCR [Tool Shed]
The shed is one of the those aluminum siding things.  Its door is open.
END_NOUN_DESCR

NOUN [Pile of sails]
sails
Pile
You see a large pile of sails here.
LOCATION [In Large Cavern]
SIZE 25 (* Wont fit through crack *)
WEIGHT 25 (* Wont fit through crack *)
NOUN_SYNONYMS PILE SAIL
END_NOUN

NOUN_DESCR [Pile of sails]
The sails are just large enough for a small boat.
END_NOUN_DESCR

NOUN [Precut lumber]
lumber
precut
You see a some precut lumber here.
LOCATION [In Large Cavern]
SIZE 25 (* Wont fit through crack *)
WEIGHT 25 (* Wont fit through crack *)
NOUN_SYNONYMS WOOD
END_NOUN

NOUN_DESCR [Precut lumber]
The lumber looks like it has been precut for building a small boat.
END_NOUN_DESCR

ROOM [Top of Hill]
Top of Hill
DOWN [Foot of Hill]
END_ROOM

ROOM_DESCR [Top of Hill]
You are on the top of small hill.  Below you is Pirate's Island.  A path
leads down.
END_ROOM_DESCR

COMMAND GO PATH
AtLocation [Top of Hill]
GoToRoom [Foot of Hill]
PrintMessage "You climb down the path to the bottom of the hill."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO CRACK
AtLocation [Top of Hill]
LoadWeightLT 20
GoToRoom [In Large Cavern]
PrintMessage [You just manage to squeeze]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO CRACK
AtLocation [Top of Hill]
LoadWeightGT 19
PrintMessage [You can't squeeze through the crack.]
DoneWithTurn
END_COMMAND

MESSAGE [You just manage to squeeze]
You just manage to squeeze through the crack to the other side.
END_MESSAGE

MESSAGE [You can't squeeze through the crack.]
You can't squeeze through the crack.  Something you are carrying gets stuck as
you try and you can't get through.
END_MESSAGE

NOUN [Narrow crack in the rock]
crack
Narrow
There is a rock wall with a narrow crack in it.
NOUN_SYNONYMS WALL
LOCATION [Top of Hill]
UNMOVABLE
END_NOUN

NOUN_DESCR [Narrow crack in the rock]
The crack in the rock wall is quite narrow.  The crack leads into a cave in
the hill.
END_NOUN_DESCR

ROOM [Maze of Caves 19]
Maze of Caves
EAST [Maze of Caves 7]
WEST [Maze of Caves 12]
LIGHT [blazing torch]
END_ROOM

ROOM_DESCR [Maze of Caves 19]
You are in a maze of caves.
END_ROOM_DESCR

ROOM [On Pirate Ship]
On Pirate Ship
END_ROOM

ROOM_DESCR [On Pirate Ship]
You are aboard a pirate ship anchored off-shore a small tropical island.
END_ROOM_DESCR

FLAG [Has sailed to 'Treasure Island']

COMMAND GO ASHORE
FlagON [Has sailed to 'Treasure Island']
AtLocation [On Pirate Ship]
SendToRoom [Dinghy] [On Beach]
SendToRoom [Wicked-looking pirate] [On Beach]
GoToRoom [On Beach]
PrintMessage "You row your dinghy to the island."
TurnFlagON [On Treasure Island]
BlankLine
DoneWithTurn
END_COMMAND

ROOM [On Beach]
On Beach
SOUTH [Graveyard]
END_ROOM

ROOM_DESCR [On Beach]
You are on the beach at treasure island.  Your ship is anchored off-shore.
There is a graveyard to the south.
END_ROOM_DESCR

NOUN [Dinghy]
dinghy
small
Your dinghy is on the beach.  Half in and half out of the water.
LOCATION [NoWhere]
UNMOVABLE
NOUN_SYNONYMS SHORE ASHORE
END_NOUN

NOUN_DESCR [Dinghy]
The dinghy is quite small.  It is half in and half out of the water on the
edge of the water.
END_NOUN_DESCR

COMMAND GO BOAT
AtLocation [On Beach]
GoToRoom [On Pirate Ship]
PrintMessage "You row your dinghy out to the pirate ship."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO DINGHY
AtLocation [On Beach]
GoToRoom [On Pirate Ship]
PrintMessage "You row your dinghy out to the pirate ship."
BlankLine
DoneWithTurn
END_COMMAND

ROOM [Graveyard]
Graveyard
NORTH [On Beach]
EAST [Barren Field]
END_ROOM

ROOM_DESCR [Graveyard]
You are in a spooky graveyard.  It is full of empty and broken rum bottles.
END_ROOM_DESCR

NOUN [Mouldy old bones]
bones
Mouldy
There are some mouldy old bones here.
LOCATION [NoWhere]
END_NOUN

NOUN_DESCR [Mouldy old bones]
The bones are bleached and white.
END_NOUN_DESCR

ROOM [Barren Field]
Barren Field
WEST [Graveyard]
NORTH [Monastery]
END_ROOM

ROOM_DESCR [Barren Field]
You are in a large barren field.  There is a graveyard to the west.
END_ROOM_DESCR

FLAG [Has walked off 30 paces]

COMMAND GO 30
AtLocation [Barren Field]
TurnFlagON [Has walked off 30 paces]
PrintMessage [You walk off 30 paces.]
DoneWithTurn
END_COMMAND

COMMAND GO 30
PrintMessage [You walk off 30 paces.]
DoneWithTurn
END_COMMAND

MESSAGE [You walk off 30 paces.]
You walk off 30 paces.
END_MESSAGE

NOUN [Wooden Box]
Box
Wooden
There is a small wooden box here.
LOCATION [NoWhere]
WEIGHT 20
SIZE 20
CLOSEABLE
CLOSED
NOUN_SYNONYMS LID
END_NOUN

NOUN_DESCR [Wooden Box]
The wooden box is about six inches square.  It has a lid on one end.
END_NOUN_DESCR

NOUN [Rare old priceless stamps]
stamps
priceless
There are some rare old priceless stamps here.
LOCATION [Wooden Box]
POINTS 50 (* one of two treasures in game *)
WEIGHT 10
SIZE 10
END_NOUN

NOUN_DESCR [Rare old priceless stamps]
The stamps are a very rare commemorative series of great adventurers.  You
see your own face smiling up on one of the priceless stamps.
END_NOUN_DESCR

COMMAND GO GRAVEYARD
AtLocation [Barren Field]
GoToRoom [Graveyard]
PrintMessage "You walk west to the graveyard."
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GO MONASTERY
AtLocation [Barren Field]
GoToRoom [Monastery]
PrintMessage "You walk north to the monastery."
BlankLine
DoneWithTurn
END_COMMAND

NOUN [Noun Monastery]
Monastery
Monastery
And there is a Monastery to the north.
LOCATION [Barren Field]
END_NOUN

NOUN_DESCR [Noun Monastery]
The Monastery looks quite old.
END_NOUN_DESCR


ROOM [Shallow Lagoon]
Shallow Lagoon
NORTH [In Ocean]
SOUTH [Sandy Beach]
EAST [Sandy Beach]
WEST [Sandy Beach]
END_ROOM

ROOM_DESCR [Shallow Lagoon]
You are in a shallow lagoon.  There is beach to the south, east and west.
END_ROOM_DESCR

COMMAND GO BEACH
AtLocation [Shallow Lagoon]
GoToRoom [Sandy Beach]
PrintMessage "You walk back up to the beach."
BlankLine
DoneWithTurn
END_COMMAND

NOUN [The tide is coming in]
tide
The
The ocean is to the north.  The tide is coming in.
LOCATION [NoWhere]
NOUN_SYNONYMS OCEAN
UNMOVABLE
END_NOUN

NOUN_DESCR [The tide is coming in]
The tide is coming in.  The waves are quite large and are breaking against the
sand.
END_NOUN_DESCR

NOUN [The tide is out]
tide
The
The ocean is to the north.  The tide is out.
LOCATION [Shallow Lagoon]
NOUN_SYNONYMS OCEAN
UNMOVABLE
END_NOUN

NOUN_DESCR [The tide is out]
The tide is going out.  The water is quite shallow.
END_NOUN_DESCR

NOUN [Flotsam and jetsam]
Flotsam
Jetsam
There is a flotsam and jetsam here.
LOCATION [NoWhere]
NOUN_SYNONYMS JETSAM
END_NOUN

NOUN_DESCR [Flotsam and jetsam]
The flotsam and jetsam consist of broken sea shells, some seaweed, pieces of
wood, a smashed milk cartoon, i.e., it is just garbage and is of little
interest to a big-time adventurer like you.  Ignore it.
END_NOUN_DESCR

NOUN [Rusty anchor]
anchor
Rusty
There is a rusty anchor half-buried in the sand.
LOCATION [Shallow Lagoon]
UNMOVABLE
END_NOUN

NOUN_DESCR [Rusty anchor]
The anchor is quite rusty.  It is stuck in the sand.
END_NOUN_DESCR

NOUN [anchor]
anchor
Rusty
There is a rusty anchor here.
LOCATION [NoWhere]
WEIGHT 30
SIZE 30
END_NOUN

NOUN_DESCR [anchor]
The anchor is quite rusty and quite heavy.
END_NOUN_DESCR

ROOM [Monastery]
Monastery
SOUTH [Barren Field]
END_ROOM

ROOM_DESCR [Monastery]
You are in a sacked and deserted monastery.
END_ROOM_DESCR

NOUN [Deadly mamba snakes]
snakes
mamba
The ground is covered by deadly mamba snakes.  They are everywhere.
LOCATION [Monastery]
NOUN_SYNONYMS SNAKE
PLURAL
END_NOUN

NOUN_DESCR [Deadly mamba snakes]
The mamba snakes are all over this place.  They are very deadly.  One bite and
you are history!
END_NOUN_DESCR

NOUN [Doubloons]
Doubloons
Gold
There are a bunch of gold doubloons here.
LOCATION [Monastery]
PLURAL
POINTS 50 (* one of two treasures in the game *)
END_NOUN

NOUN_DESCR [Doubloons]
The gold doubloons must be worth a great deal of money.
END_NOUN_DESCR

ROOM [Never-Never land]
Never-Never land
END_ROOM

ROOM_DESCR [Never-Never land]

You are in Never-Never land.
END_ROOM_DESCR


FLAG [Question Flag]

NOUN [Dummy noun #1]
Graveyard
small
This is a dummy noun
LOCATION [NoWhere]
UNMOVABLE
END_NOUN

NOUN [Dummy noun #2]
cave
small
This is a dummy noun
LOCATION [NoWhere]
UNMOVABLE
END_NOUN

NOUN [Dummy noun #3]
pit
small
This is a dummy noun
LOCATION [NoWhere]
UNMOVABLE
END_NOUN

NOUN [Dummy noun #4]
hallway
small
This is a dummy noun
LOCATION [NoWhere]
UNMOVABLE
END_NOUN

FLAG [Start of Game]         Beginning of game flag
FLAG [bottle full]           Bottle has liquid in it if ON, is empty if OFF

;AUTOMATIC COMMANDS
;Set FLAGS based on game or room status

COMMAND ANY
FlagOFF [Start of Game] ;first turn of game only - initialize conditions
TurnFlagON [Start of Game]
TurnFlagON [bottle full]
END_COMMAND

(***************************************************)
(*  Automatic commands whenever player is swimming *)
(*  -- matches get soggy                           *)
(*  -- torch goes out                              *)
(***************************************************)

COMMAND ANY
AtLocation [In Ocean]
Present [Wooden matches]
SwapLocations [Wooden matches] [soggy matches]
END_COMMAND

COMMAND ANY
AtLocation [In Ocean]
Present [blazing torch] (* blazing torch *)
SwapLocations [blazing torch] [unlit torch]  (* swap with unlit torch *)
TurnCounterOFF [Number of turns torch has been lit]
END_COMMAND

FLAG [Has befriended parrot]

COUNTER [Number of turns torch has been lit]
COUNTER [Stumbling around in the dark]
#COMMENT Number of turns player has been stumbling around in the dark

(***************************************************)
(*  Automatic commands to control time torch is ON *)
(*   -- Torch starts to flicker at 25 turns        *)
(*   -- Torch goes off at 50 turns                 *)
(*   -- Player dies if he stumbles around in dark  *)
(*      for 5 turns                                *)
(***************************************************)

COMMAND ANY
Present [blazing torch]
CounterEquals [Number of turns torch has been lit] 25
PrintMessage [The light flickers and the torch grows weaker.]
RoomNeedsLight (* will be dark if no light *)
PrintMessage [You better find a way out of here pretty quick!]
END_COMMAND

COMMAND ANY
Present [blazing torch]
CounterGT [Number of turns torch has been lit] 25
CounterLT [Number of turns torch has been lit] 50
PrintMessage [The light flickers and the torch grows weaker.]
END_COMMAND

COMMAND ANY
Present [blazing torch]
CounterEquals [Number of turns torch has been lit] 50
PrintMessage [Sorry, but your torch light flickers and goes out.]
SwapLocations [blazing torch] [unlit torch]
Destroy [Wooden matches]
RoomNeedsLight (* will be dark if no light *)
TurnCounterON [Stumbling around in the dark]
LookAtRoom
END_COMMAND

COMMAND ANY
RoomNeedsLight (* will be dark if no light *)
NOT LightPresent (* no light in room *)
CounterEquals [Stumbling around in the dark] 0
PrintMessage [Stumbling around in the dark could be quite dangerous!]
TurnCounterON [Stumbling around in the dark]
END_COMMAND

COMMAND ANY
CounterGT [Stumbling around in the dark] 1
RoomNeedsLight (* will be dark if no light *)
NOT LightPresent (* no light in room *)
PrintMessage [Stumbling around in the dark could be quite dangerous!]
CounterEquals [Stumbling around in the dark] 5
GoToRoom [Never-Never land]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND ANY
CounterGT [Stumbling around in the dark] 5
RoomNeedsLight (* will be dark if no light *)
NOT LightPresent (* no light in room *)
TurnCounterON [Stumbling around in the dark]
END_COMMAND

MESSAGE [The light flickers and the torch grows weaker.]
The light flickers and the torch grows weaker.
END_MESSAGE

MESSAGE [You better find a way out of here pretty quick!]
If I were you, I would find a way out of here pretty quick before the torch
goes out!  This would not be a fun place to be caught stumbling around in the
dark.
END_MESSAGE

MESSAGE [Sorry, but your torch light flickers and goes out.]
Sorry, but your torch light flickers for the last time and goes out.
END_MESSAGE

MESSAGE [Stumbling around in the dark could be quite dangerous!]
You are stumbling around in the dark -- which could be quite dangerous!  You
could easily break your neck.
END_MESSAGE


(***************************************************)
(*  Automatic commands to control meeting parrot     *)
(*  and have parrot follow player and speak          *)
(***************************************************)

FLAG [Has met parrot]

COMMAND ANY
Present [parrot]
FlagOFF [Has met parrot]
PrintMessage "The parrot squawks -- 'Polly wants a cracker!!'"
BlankLine
TurnFlagON [Has met parrot]
END_COMMAND

COMMAND ANY
IsSomewhere [parrot] (* parrot exists *)
FlagON [Has befriended parrot]
PutInCurrentRoom [parrot] (* put parrot in room *)
VerbIsDirection (* moving to another location *)
PrintMessage "The parrot flies along behind you."
BlankLine
END_COMMAND

COMMAND ANY
Chance 5
Present [parrot]
PrintMessage [The parrot sings - "Sixteen men on a dead man's chest..."]
BlankLine
END_COMMAND

MESSAGE [The parrot sings - "Sixteen men on a dead man's chest..."]
The parrot starts singing - "Sixteen men on a dead man's chest..."
END_MESSAGE

COMMAND ANY
Chance 35
Present [parrot]
IsLocated [Wooden matches] [Duffle bag]
PrintMessage [The parrot cries out - "check the bag!"]
BlankLine
END_COMMAND

MESSAGE [The parrot cries out - "check the bag!"]
The parrot cries out - "check the bag!"
END_MESSAGE

COMMAND ANY
Chance 10
Present [parrot]
IsLocated [Map] [treasure chest]
PrintMessage [The parrot cries out - "check the chest!"]
BlankLine
END_COMMAND

MESSAGE [The parrot cries out - "check the chest!"]
The parrot cries out - "check the chest!"
END_MESSAGE

FLAG [On Treasure Island]

COMMAND ANY
FlagOFF [On Treasure Island]
Chance 80
InRoom [rum bottle]
Present [Wicked-looking pirate]
Destroy [Wicked-looking pirate]
SendToRoom [Sleeping pirate] [Musty Attic]
SendToRoom [rum bottle] [Musty Attic]
PrintMessage [The pirate grabs the rum and scuttles off chortling]
DoneWithTurn
END_COMMAND

COMMAND ANY
FlagON [On Treasure Island]
Chance 80
InRoom [rum bottle]
Present [Wicked-looking pirate]
Destroy [Wicked-looking pirate]
SendToRoom [Sleeping pirate] [Graveyard]
SendToRoom [rum bottle] [Graveyard]
PrintMessage [The pirate grabs the rum and scuttles off chortling]
DoneWithTurn
END_COMMAND

COMMAND ANY
Chance 50
AtLocation [In Ocean]
DescribeThing [The tide is coming in]
BlankLine
NOT IsCarrying [Water wings]
PrintMessage [You drowned]
GoToRoom [Never-never land]
DoneWithTurn
END_COMMAND

COMMAND ANY
Chance 35
NOT Present [water bottle]
Present [mackerel]
Destroy [mackerel]
SendToRoom [fish] [In Ocean]
PrintMessage "The fish are too dry.  They died, and strangely enough, vanished!"
DoneWithTurn
END_COMMAND

COMMAND ANY
Chance 80
InRoom [mackerel]
Present [Mean and hungry looking crocodiles]
Destroy [mackerel]
Destroy [Mean and hungry looking crocodiles]
PrintMessage [The crocs eat the fish and leave]
DoneWithTurn
END_COMMAND

FLAG [Tide is changing]

COMMAND ANY
Chance 10
SwapLocations [The tide is coming in] [The tide is out]
TurnFlagON [Tide is changing]
END_COMMAND

COMMAND ANY
FlagON [Tide is changing]
IsNoWhere [anchor] (* Player has not dug up anchor yet *)
SwapLocations [Rusty anchor] [Flotsam and jetsam]
END_COMMAND

COMMAND ANY
FlagON [Tide is changing]
Present [Parrot]
PrintMessage [Parrot cries - "the tide is changing, matey."]
BlankLine
END_COMMAND

COMMAND ANY
FlagON [Tide is changing]
TurnFlagOFF [Tide is changing]
END_COMMAND

COMMAND ANY
Chance 50
AtLocation [Shallow Lagoon]
Present [The tide is coming in]
DescribeThing [The tide is coming in]
BlankLine
NOT IsCarrying [Water wings]
PrintMessage [You drowned]
GoToRoom [Never-never land]
DoneWithTurn
END_COMMAND

MESSAGE [You drowned]
You are suddenly underwater!  Then you remember that you can't swim!
....blub...blub...blub....
END_MESSAGE
COMMAND ANY
Chance 3
InRoom [parrot]
PrintMessage [The parrot cries out - "pieces of eight."]
BlankLine
END_COMMAND

COMMAND ANY
Chance 80
InRoom [Mongoose]
Present [Deadly mamba snakes]
Destroy [Mongoose]
PrintMessage [The snakes bit the mongoose and run it off.]
BlankLine
END_COMMAND

MESSAGE [The snakes bit the mongoose and run it off.]
You are surprised to see the deadly mamba snakes bite the mongoose and drive
it off.
END_MESSAGE

COMMAND ANY
Chance 80
InRoom [parrot]
Present [Deadly mamba snakes]
Destroy [Deadly mamba snakes]
PrintMessage [The parrot cries out - "pieces of eight."]
BlankLine
PrintMessage [The parrot attacks the snakes]
DoneWithTurn
END_COMMAND

MESSAGE [The parrot cries out - "pieces of eight."]
The parrot cries out - "pieces of eight."
END_MESSAGE

MESSAGE [The parrot attacks the snakes]
The parrot attacks the deadly mamba snakes and drives them off.
END_MESSAGE

COMMAND ANY
AtLocation [Never-Never land]
PrintMessage "Nothing happened."
BlankLine
TurnFlagON [Question Flag]
AskQuestion [Another game (Yes or No)?]
AnswerIsCorrect (* Answered YES *)
GoToRoom [London Apartment]
TurnFlagOFF [Question Flag]
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation [Never-Never land]
FlagON [Question Flag] (* Answered NO *)
EndGame
DoneWithTurn
END_COMMAND

#DEFINE [Another game (Yes or No)?]  1

QUESTION [Another game (Yes or No)?] Another game (Yes or No)?
ANSWER [Another game (Yes or No)?] YES

COMMAND SCORE
AtLocation [London Apartment]
Present [Doubloons]
Present [Rare old priceless stamps]
PrintMessage "You are a noble and brave adventurer!  You are also a winner!"
BlankLine
EndGame
DoneWithTurn
END_COMMAND

COMMAND SAY
PrintMessage "Use one word, i.e., $NOUN$ only."
DoneWithTurn
END_COMMAND

COMMAND AWAY ANY
PrintMessage "Sorry, wrong game!"
DoneWithTurn
END_COMMAND

COMMAND GET ANY
Present [Wicked-looking pirate]
PrintMessage [The pirate wont let you]
DoneWithTurn
END_COMMAND

COMMAND GET FLOTSAM
PrintMessage "Don't be silly!  Quit screwing around!"
DoneWithTurn
END_COMMAND

COMMAND GET SIGN
PrintMessage "A voice booms out -- LEAVE THE $NOUN$ ALONE, TURKEY!!"
DoneWithTurn
END_COMMAND

COMMAND GET RUG
Present [Rug in room]
PrintMessage "You can't get the rug without something to pry the nails up."
DoneWithTurn
END_COMMAND

COMMAND GET NAILS
FlagOFF [Has nails out of box lid]
Present [Wooden box]
NOT Present [Claw hammer]
PrintMessage "You don't have the necessary resources!"
DoneWithTurn
END_COMMAND

COMMAND GET NAILS
FlagOFF [Has nails out of box lid]
Present [Wooden box]
Present [Claw hammer]
PrintMessage [You pry out the nails on the box's lid.]
DropIT [Nails]
TurnFlagON [Has nails out of box lid]
DoneWithTurn
END_COMMAND

MESSAGE [You pry out the nails on the box's lid.]
You pry the nails out of the box's lid.
END_MESSAGE

COMMAND GET NAILS
Present [Rug in room]
NOT Present [Claw hammer]
PrintMessage "You can't get the nails without something to pry them up."
DoneWithTurn
END_COMMAND

COMMAND GET NAILS
Present [Rug in room]
Present [Claw hammer]
PrintMessage "You pry the nails up with the clay hammer."
GetIt [Nails]
SwapLocations [Rug] [Rug in room]
DoneWithTurn
END_COMMAND

COMMAND GET RUG
AtLocation [London Apartment]
Present [Rug]
PrintMessage "There is something under the rug."
GetIt [Rug]
PutInCurrentRoom [ring of keys]
DoneWithTurn
END_COMMAND

COMMAND GET SAND
PrintMessage [You play in the sand for a while.]
DoneWithTurn
END_COMMAND

COMMAND GET BOOK
AtLocation [Alcove]
Present [Large leather bound book]
NOT Present [secret passage]
PutInCurrentRoom [secret passage]
PrintMessage "The bookcase slides back to reveal a secret passage."
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND GET PARROT
Present [parrot]
NOT Present [Wicked-looking pirate]
PrintMessage "The parrot flies out of your grasp."
DoneWithTurn
END_COMMAND

COMMAND GET ANCHOR
Present [Rusty anchor]
Present [shovel]
GetIt [anchor]
Destroy [Rusty anchor]
PrintMessage [You manage to dig the anchor out of the sand.]
DoneWithTurn
END_COMMAND

COMMAND GET FISH
Present [fish]
Destroy [fish]
GetIT [mackerel]
PrintMessage "You manage to catch the fish with your bare hands."
DoneWithTurn
END_COMMAND

COMMAND GET DOUBLOONS
Present [Doubloons]
Present [Deadly mamba snakes]
PrintMessage [You get bit]
GoToRoom [Never-never land]
DoneWithTurn
END_COMMAND

MESSAGE [You get bit]
As your reach for the doubloons, the deadly mamba snakes bite you.  Too bad!
END_MESSAGE

COMMAND GET WATER
FlagON [bottle full]
PrintMessage [already full]
DoneWithTurn
END_COMMAND

MESSAGE [already full]
The bottle is already full.
END_MESSAGE

COMMAND GET WATER
NOT Present [empty bottle]
PrintMessage [nothing to put it in]
DoneWithTurn
END_COMMAND
MESSAGE [nothing to put it in]
You have nothing in which to carry it.
END_MESSAGE

COMMAND GET WATER
AtLocation [In Ocean]
PrintMessage [bottle now full of water]
SwapLocations [empty bottle] [water bottle]
TurnFlagON [bottle full]
DoneWithTurn
END_COMMAND

MESSAGE [bottle now full of water]
The bottle is now full of sea water.
END_MESSAGE

COMMAND GET WATER
Present [empty bottle]
PrintMessage [no liquid here]
DoneWithTurn
END_COMMAND

MESSAGE [no liquid here]
There is nothing here with which to fill the bottle.
END_MESSAGE

COMMAND WAKE PIRATE
Present [Sleeping pirate]
PrintMessage [The pirate says - 'Aye matey, we be casting off soon]
SendToRoom [Wicked-looking pirate] [On Pirate Ship]
DoneWithTurn
END_COMMAND

MESSAGE [The pirate says - 'Aye matey, we be casting off soon]
The pirate says - 'Aye matey, we be casting off soon."  He then runs away.
Just as he disappears out of sight, he cries out - 'Hurry, matey, the tide is
changing!"
END_MESSAGE

COMMAND PLAY SAND
PrintMessage [You play in the sand for a while.]
DoneWithTurn
END_COMMAND

MESSAGE [You play in the sand for a while.]
You play in the sand for a while.  But eventually you get bored and stop.
END_MESSAGE

COMMAND JUMP
AtLocation [Outside Window]
PrintMessage "Don't be silly!  That would be dangerous!"
DoneWithTurn
END_COMMAND

COMMAND JUMP
PrintMessage "Don't be silly!  Quit screwing around!"
DoneWithTurn
END_COMMAND

COMMAND YOHO
AtLocation [Outside Window]
IsCarrying [Large leather bound book]
IsWearing [Non-skid sneakers]
GoToRoom [Sandy Beach]
PrintMessage [Everything spins around and suddenly you are elsewhere...]
BlankLine
DoneWithTurn
END_COMMAND

COMMAND YOHO
AtLocation [Sandy Beach]
IsCarrying [Large leather bound book]
IsWearing [Non-skid sneakers]
GoToRoom [Outside Window]
PrintMessage [Everything spins around and suddenly you are elsewhere...]
BlankLine
DoneWithTurn
END_COMMAND

MESSAGE [Everything spins around and suddenly you are elsewhere...]
Everything spins around and suddenly you are elsewhere...
END_MESSAGE

COMMAND YOHO
PrintMessage "Don't be silly!  Quit screwing around!"
DoneWithTurn
END_COMMAND

COMMAND HELP
AtLocation [Sandy Beach]
OR
AtLocation [Outside Window]
PrintMessage [You may need magic here.]
DoneWithTurn
END_COMMAND

MESSAGE [You may need magic here.]
You may need magic here.
END_MESSAGE

COMMAND HELP
RoomNeedsLight (* will be dark if no light *)
NOT LightPresent (* no light in room *)
PrintMessage [You are in real trouble...]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [You are in real trouble...]
It is pitch black in here and you can't see your hand in front of your face.
You are really in deep weeds!  Sorry, I can't help you.  You got yourself into
this mess, so you will just have to get yourself out of it!
END_MESSAGE

FLAG [Has built boat]

COMMAND BUILD BOAT
FlagOFF [Has built boat]
Present [Claw hammer]
Present [Small ship's keel and mast]
Present [Set of plans]
Present [anchor]
Present [Nails]
Present [Pile of sails]
Present [Precut lumber]
TurnFlagON [Has built boat]
END_COMMAND

COMMAND BUILD BOAT
FlagON [Has built boat] -- continuation of previous COMMAND
SendToRoom [pirate ship] [Shallow Lagoon]
PrintMessage [You build a boat]
BlankLine
PrintMessage [Congratulations!  But your adventure isn't over yet.]
Destroy [Small ship's keel and mast]
Destroy [anchor]
Destroy [Nails]
Destroy [Pile of sails]
Destroy [Precut lumber]
DoneWithTurn
END_COMMAND

MESSAGE [You build a boat]
You work like a fiend possessed with a lust for adventure and treasure.
As you drive the last nail, the ship disappears -- like magic!
END_MESSAGE

MESSAGE [Congratulations!  But your adventure isn't over yet.]
Congratulations!  But your adventure isn't over yet.
END_MESSAGE

COMMAND BUILD BOAT
NOT Present [Set of plans]
PrintMessage "You need to have some plans - or it will be a mess - not a boat."
DoneWithTurn
END_COMMAND

COMMAND BUILD BOAT
PrintMessage "Something is missing that you need to build a boat."
DoneWithTurn
END_COMMAND

COMMAND KILL PIRATE
Present [Wicked-looking pirate]
PrintMessage "'Don't even think about it - matey!'"
DoneWithTurn
END_COMMAND

COMMAND UNLOCK ANY
Present [Wicked-looking pirate]
PrintMessage [The pirate wont let you]
DoneWithTurn
END_COMMAND

COMMAND UNLOCK ANY
Present [Mean and hungry looking crocodiles]
PrintMessage [The crocodiles wont let you]
DoneWithTurn
END_COMMAND

MESSAGE [The pirate wont let you]
As your reach for the $noun$, the wicked-looking pirate snarls -- "leave
it alone, matey!"  You decide to follow his advise.
END_MESSAGE

COMMAND UNLOCK DOOR
AtLocation [In a Pit]
Present [Locked door #2]
NOT Present [Mean and hungry looking crocodiles]
Present [ring of keys]
SwapLocations [Locked door #2] [Open doorway with hallway beyond]
SwapLocations [Locked door] [Open doorway with pit beyond]
PrintMessage "You unlock the door and swing it open revealing a hallway beyond."
DoneWithTurn
END_COMMAND

COMMAND GIVE RUM TO PIRATE
FlagOFF [On Treasure Island]
Present [rum bottle]
Present [Wicked-looking pirate]
Destroy [Wicked-looking pirate]
SendToRoom [Sleeping pirate] [Musty Attic]
SendToRoom [rum bottle] [Musty Attic]
PrintMessage [The pirate grabs the rum and scuttles off chortling]
DoneWithTurn
END_COMMAND

COMMAND GIVE RUM TO PIRATE
FlagON [On Treasure Island]
Present [rum bottle]
Present [Wicked-looking pirate]
Destroy [Wicked-looking pirate]
SendToRoom [Sleeping pirate] [Graveyard]
SendToRoom [rum bottle] [Graveyard]
PrintMessage [The pirate grabs the rum and scuttles off chortling]
DoneWithTurn
END_COMMAND
MESSAGE [The pirate grabs the rum and scuttles off chortling]
The pirate grabs the rum and scuttles off chortling.
END_MESSAGE

COMMAND GIVE FISH TO CROCODILES
Present [mackerel]
Present [Mean and hungry looking crocodiles]
Destroy [mackerel]
Destroy [Mean and hungry looking crocodiles]
PrintMessage [The crocs eat the fish and leave]
DoneWithTurn
END_COMMAND

MESSAGE [The crocs eat the fish and leave]
The crocodiles eat the fish and leave.
END_MESSAGE

COMMAND GIVE CRACKERS TO PARROT
NOT Present [Wicked-Looking Pirate]
Present [parrot]
Present [Crackers]
Destroy [Crackers]
PrintMessage [The parrot eats crackers]
TurnFlagON [Has befriended parrot]
DoneWithTurn
END_COMMAND

MESSAGE [The Parrot eats crackers]
The parrot eats all the crackers and becomes your friend.
END_MESSAGE

COMMAND WEIGH ANCHOR
PrintMessage "About 60 pounds.  Try 'Set sail.'"
DoneWithTurn
END_COMMAND

COMMAND SAIL
PrintMessage "Try 'weigh anchor.'"
DoneWithTurn
END_COMMAND

COMMAND CAST
PrintMessage "Try 'weigh anchor.'"
DoneWithTurn
END_COMMAND

COMMAND SET SAIL
AtLocation [On Pirate Ship]
NOT Present [Wicked-looking pirate]
PrintMessage "You have no crew."
DoneWithTurn
END_COMMAND

COMMAND SET SAIL
AtLocation [On Pirate Ship]
NOT Present [map]
PrintMessage "The pirate says 'Aye matey we be needing a map first.'"
DoneWithTurn
END_COMMAND

COMMAND SET SAIL
AtLocation [On Pirate Ship]
Present [Wicked-looking pirate]
IsSomeWhere [The tide is out]
PrintMessage [The pirate says - ' Aye matey, we be waiting for the tide]
DoneWithTurn
END_COMMAND

MESSAGE [The pirate says - ' Aye matey, we be waiting for the tide]
The pirate says - ' Aye matey, we be waiting for the tide to come in.'
END_MESSAGE

#COMMENT -- Sail to 'Treasure Island'

COMMAND SET SAIL
FlagOFF [Has sailed to 'Treasure Island']
AtLocation [On Pirate Ship]
Present [Wicked-looking pirate]
IsSomeWhere [The tide is coming in]
TurnFlagON [Has sailed to 'Treasure Island']
PrintMessage [You sail off for a couple of days]
DoneWithTurn
END_COMMAND

#COMMENT -- Sail from 'Treasure Island' to original island

COMMAND SET SAIL
FlagON [Has sailed to 'Treasure Island']
AtLocation [On Pirate Ship]
Present [Wicked-looking pirate]
IsSomeWhere [The tide is coming in]
TurnFlagOFF [Has sailed to 'Treasure Island']
PrintMessage [You sail off for a couple of days]
DoneWithTurn
END_COMMAND

MESSAGE [You sail off for a couple of days]
You sail for a couple of days.  Finally, you anchor off-shore of a tiny
tropical island.
END_MESSAGE

COMMAND WAIT
SwapLocations [The tide is coming in] [The tide is out]
TurnFlagON [Tide is changing]
END_COMMAND

COMMAND WAIT
FlagON [Tide is changing]
IsNoWhere [anchor] (* Player has not dug up anchor yet *)
SwapLocations [Rusty anchor] [Flotsam and jetsam]
END_COMMAND

COMMAND WAIT
FlagON [Tide is changing]
Present [Parrot]
PrintMessage [Parrot cries - "the tide is changing, matey."]
END_COMMAND

MESSAGE [Parrot cries - "the tide is changing, matey."]
The parrot cries - 'The tide is changing, matey.'
END_MESSAGE

COMMAND WAIT
FlagON [Tide is changing]
TurnFlagOFF [Tide is changing]
DoneWithTurn
END_COMMAND

COMMAND DIG
Present [Shovel]
AtLocation [On Beach]
NOT Present [Rum bottle]
DropIt [Rum bottle]
PrintMessage "You dig up a bottle of rum."
DoneWithTurn
END_COMMAND

COMMAND DIG
Present [Shovel]
AtLocation [Graveyard]
DropIt [Mouldy old bones]
PrintMessage "You dig up a bunch of mouldy old bones.  Ugh!"
DoneWithTurn
END_COMMAND

COMMAND DIG
Present [Shovel]
AtLocation [Barren Field]
FlagON [Has walked off 30 paces]
DropIt [Wooden Box]
PrintMessage "You dig up a small wooden box."
DoneWithTurn
END_COMMAND

COMMAND DIG
Present [Rusty anchor]
Present [shovel]
GetIt [anchor]
Destroy [Rusty anchor]
PrintMessage [You manage to dig the anchor out of the sand.]
DoneWithTurn
END_COMMAND
MESSAGE [You manage to dig the anchor out of the sand.]
You manage to dig the anchor out of the sand.
END_MESSAGE

COMMAND DIG
Present [Shovel]
PrintMessage "You dig up a small hole, but don't find anything."
DoneWithTurn
END_COMMAND

COMMAND DIG
NOT Present [Shovel]
PrintMessage "You don't have the necessary resources!"
DoneWithTurn
END_COMMAND

COMMAND BURY
Present [Shovel]
PrintMessage "The ground is to hard and you give up."
DoneWithTurn
END_COMMAND

COMMAND BURY
NOT Present [Shovel]
PrintMessage "You don't have the necessary resources!"
DoneWithTurn
END_COMMAND

COMMAND PUT WATER IN BOTTLE
ReDirectTo GET WATER
END_COMMAND

COMMAND PUT RUM
ReDirectTo POUR RUM
END_COMMAND

COMMAND PUT WATER
ReDirectTo POUR WATER
END_COMMAND

COMMAND POUR WATER
Present [water bottle]
SwapLocations [water bottle] [empty bottle]
PrintMessage [bottle empty, ground wet]
PrintMessage [feet now wet]
TurnFlagOFF [bottle full]
DoneWithTurn
END_COMMAND

MESSAGE [feet now wet]
Your feet are now wet.
END_MESSAGE

COMMAND POUR RUM
Present [rum bottle]
SwapLocations [rum bottle] [empty bottle]
PrintMessage [bottle empty, ground wet]
PrintMessage [What a pity!]
TurnFlagOFF [bottle full]
DoneWithTurn
END_COMMAND

MESSAGE [What a pity!]
Your feet are now wet.  What a waste!  What a pity!
END_MESSAGE

COMMAND DRINK WATER
Present [water bottle]
PrintMessage [bottle now empty]
BlankLine
PrintMessage [Ugh! You die!]
SwapLocations [empty bottle] [water bottle]
TurnFlagOFF [bottle full]
GoToRoom [Never-never land]
DoneWithTurn
END_COMMAND

MESSAGE [Ugh! You die!]
Ugh!  The sea water is polluted and you eventually die from its effects!
END_MESSAGE

MESSAGE [bottle now empty]
The bottle is now empty.
END_MESSAGE

COMMAND DRINK RUM
Present [rum bottle]
PrintMessage [bottle now empty]
BlankLine
PrintMessage [Ugh!  This is real rot-gut!]
SwapLocations [empty bottle] [rum bottle]
TurnFlagOFF [bottle full]
DoneWithTurn
END_COMMAND

MESSAGE [Ugh!  This is real rot-gut!]
Ugh!  This stuff is real rot-gut!  However, it is really potent -- about 150
proof -- at least!  Boy-Oh-Boy do you feel good!  Hee hee...
END_MESSAGE

COMMAND DRINK ANY
PrintMessage [don't be ridiculous]
DoneWithTurn
END_COMMAND

COMMAND CLOSE BOTTLE
Present [rum bottle]
OR
Present [empty bottle]
OR
Present [water bottle]
PrintMessage "Ok.  It is now closed."
DoneWithTurn
END_COMMAND

COMMAND BREAK
PrintMessage "It is beyond your power to do that."
DoneWithTurn
END_COMMAND

COMMAND FILL BOTTLE
FlagON [bottle full]
PrintMessage [already full]
DoneWithTurn
END_COMMAND

COMMAND FILL BOTTLE
NOT Present [empty bottle]
PrintMessage [nothing to put it in]
DoneWithTurn
END_COMMAND

COMMAND FILL BOTTLE
AtLocation [In Ocean]
PrintMessage [bottle now full of water]
SwapLocations [empty bottle] [rum bottle]
TurnFlagON [bottle full]
DoneWithTurn
END_COMMAND

COMMAND FILL BOTTLE
PrintMessage [no liquid here]
DoneWithTurn
END_COMMAND

COMMAND FILL ANY
PrintMessage "You can't fill that."
DoneWithTurn
END_COMMAND

MESSAGE [bottle empty, ground wet]
Your bottle is empty and the ground is wet.
END_MESSAGE

MESSAGE [don't be ridiculous]
Don't be ridiculous!
END_MESSAGE



#COMMENT -- LIGHT

COMMAND LIGHT MATCHES
Present [Wooden matches] (* dry matches *)
PrintMessage "The match burns for a few minutes and then goes out."
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND LIGHT MATCHES
Present [soggy matches]
PrintMessage [Sorry, but you can't]
PrintMessage [Your matches are too wet]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [Sorry, but you can't]
What a great idea!  You must have played this game before, but unfortunately
you can't do that now.  It is still a good idea and you may wish to try it
some other time.  But unfortunately, it is simple impossible now because --
END_MESSAGE

MESSAGE [Your matches are too wet]
your matches are too wet to light!
END_MESSAGE

COMMAND LIGHT TORCH
Present [unlit torch]
Present [Wooden matches]
SwapLocations [unlit torch] [blazing torch]
PrintMessage [OK...]
TurnCounterON [Number of turns torch has been lit]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND LIGHT TORCH
Present [unlit torch]
Present [soggy matches]
PrintMessage [Sorry, but you can't]
PrintMessage [Your matches are too wet]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND LIGHT TORCH
Present [unlit torch] (* torch *)
NOT Present [Wooden matches] (* dry matches *)
PrintMessage [Sorry, but you can't]
PrintMessage [You don't have resources]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [You don't have resources]
you don't have the necessary resources to $verb$ the $noun$.
END_MESSAGE

MESSAGE [OK...]
OK... you $verb$ the $noun$.
END_MESSAGE

COMMAND EXTINGUISH TORCH
Present [blazing torch] (* blazing torch *)
PrintMessage [OK...]
SwapLocations [unlit torch] [blazing torch]
TurnCounterOFF [Number of turns torch has been lit]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND OPEN ANY
Present [Mean and hungry looking crocodiles]
PrintMessage [The crocodiles wont let you]
DoneWithTurn
END_COMMAND

MESSAGE [The crocodiles wont let you]
As your reach for the $noun$, the crocks snap at your leg.  Since the
crocodiles look quite hungry, you decide that discretion is the better part
of valor.
END_MESSAGE

COMMAND OPEN ANY
Present [Wicked-looking pirate]
PrintMessage [The pirate wont let you]
DoneWithTurn
END_COMMAND

COMMAND OPEN BOOK
Present [Large leather bound book]
PrintMessage "You find a note - 'You be liking parrots.  They be smart matey.'"
DoneWithTurn
END_COMMAND

COMMAND OPEN BOTTLE
Present [rum bottle]
OR
Present [empty bottle]
OR
Present [water bottle]
PrintMessage "Ok.  It is now open."
DoneWithTurn
END_COMMAND

COMMAND OPEN BOOK
PrintMessage [OK...]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

FLAG [Has nails out of box lid]

COMMAND OPEN BOX
FlagOFF [Has nails out of box lid]
Present [Wooden box]
Present [Claw hammer]
PrintMessage [You pry out the nails on the box's lid.]
TurnFlagON [Has nails out of box lid]
DropIT [Nails]
DoneWithTurn
END_COMMAND

COMMAND OPEN BOX
FlagOFF [Has nails out of box lid]
Present [Wooden box]
NOT Present [Claw hammer]
PrintMessage "It is nailed shut!"
DoneWithTurn
END_COMMAND

COMMAND OPEN BOX
FlagON [Has nails out of box lid]
Present [Wooden box]
PrintMessage "You open the box by lifting the lid."
OpenIT [Wooden box]
DoneWithTurn
END_COMMAND

COMMAND TALK TO PARROT
Present [parrot]
PrintMessage [You chat with parrot]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

COMMAND ASK PARROT ABOUT ANY
Present [parrot]
PrintMessage [You chat with parrot]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [You chat with parrot]
Talking to a parrot is rather strange --even for you! You must be desperate to
solve this adventure or have other kinds of problems.  The parrot seems somewhat
amused by your attempts at communication.  He stares at you and then responds
with a loud "Polly wants a cracker!"
END_MESSAGE

COMMAND KISS ANY
PrintMessage [Don't be silly!]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [Don't be silly!]
Why on earth would your ever want to do that?  Don't you know that to
$verb$ the $noun$ would be extremely silly!
END_MESSAGE

COMMAND BREAK DOOR
PrintMessage [You charge at the door at full speed.]
DoneWithTurn (* no further action -- get next input *)
END_COMMAND

MESSAGE [You charge at the door at full speed.]
You charge at the door at full speed.  You hit it with your shoulder, bounce
off and land with a "thud" on the floor.  After rubbing the ache in your
shoulder, you stand up.  It is obvious that your body will break before the
door does!
END_MESSAGE



